Copper macro

// Written by: Coyan/Mosaic Guild
// This is what I suggest for setting up for this macro
// First align your view so you can see all 7 crystals clearly
// second use Alt-L to lock your camera angle
// Third before starting this, I suggest you have your mouse sitting over
//  the first crystal.
// You will have 3 seconds between the recording of each crystal's location
// place your mouse over the darkest part of each crystal in turn
// Once it has identified the 7 crystals, it will run the mine
Constructs
  MouseX=List // this is an array of mouse X coords for gem sample points
  MouseY=List // this is an array of mouse X coords for gem sample points
END
Constants
  loopcnt = 1 
  Mousecnt = 1
  MouseXN = 0
  MouseYN = 0
  ColorN = 0
  ColorS = 0
  Minval = 0
  Maxval = 255
  CONSTVAL = 0
  Tmpval = 0
End

Compute CONSTVAL = 100/255 // constant being set for saturation calculation

// First part that requires a detailed explanation
// this loop will pause for 3 seconds then grab the current mouse location
// its purpose is to identify the 7 sampling locations for the crystals
// when it grabs the sampling spot, it will then echo a . to the chat window
// make sure you are in your main chat tab.
Loop 7
  Delay 3000
  Listadd MouseX, {MouseX}
  Listadd MouseY, {MouseY}
  SayPaste .
END

loop 100

  Compute loopcnt = 1
  loop 7
    mousepos MouseX[$loopcnt], MouseY[$loopcnt]
    LoadRGB MouseX[$loopcnt], MouseY[$loopcnt]
    Call CALCSATCOLOR
    IF $ColorN > $ColorS
	Compute ColorS = $ColorN
	Compute Mousecnt = $loopcnt
    END
    Compute loopcnt = $loopcnt + 1
    Delay 100
  END	
	
  mousepos MouseX[$Mousecnt], MouseY[$Mousecnt]
  Delay 200 
  leftclick
  Compute MouseXN = MouseX[$Mousecnt] + 15 // adjust this if you need to for the menu click
  Compute MouseYN = MouseY[$Mousecnt] - 10 // adjust this if you need to for the menu click
  Mousepos $MouseXN, $MouseYN
  Delay 200
  Leftclick
	
  Compute ColorS = 0 //resets the color satuation for each sampling
  Delay 4200 // Delay to manage the str/perc timer on mining, adjust as needed
	
END

Procedure CALCSATCOLOR // This procedure calculates the saturation of the crystal
  Compute Minval = 0
  Compute Maxval = 255
  IF {RGBRed} > {RGBGreen}
	Compute Minval = {RGBGreen}
	Compute Maxval = {RGBRed}
  Else
	Compute Maxval = {RGBGreen}
	Compute Minval = {RGBRed}
  END
  IF {RGBBlue} < $Minval
	Compute Minval = {RGBBlue}
  ELSE
	IF {RGBBlue} > $Maxval
		Compute Maxval = {RGBBlue}
	END
  END
  Compute Tmpval = $Maxval - $Minval
  Compute Tmpval = $Tmpval / $Maxval
  Compute ColorN = $Tmpval * $CONSTVAL
END

back to Macro list: Mosaic Macros